home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 2000 #4 / Amiga Plus CD - 2000 - No. 4.iso / Tools / Patch / RemApollo / Modules / NoClick.s < prev    next >
Encoding:
Text File  |  2000-03-04  |  1.1 KB  |  57 lines
  1.  
  2. * NoClick patch module for RemAPollo
  3. * based on BlizKick [(c) Harry Sintonen] interface
  4. * Public Domain
  5. * coded by MM in 1999
  6.  
  7. * changed the way noclick is installed - it can be now examined/switched by
  8. * manipulating TDP_NOCLICK flag independently for each unit
  9.  
  10. * removed support for hackdisk.device
  11.  
  12.     moveq    #'z',d0            ;BKMODULE_ID
  13.     rts
  14.  
  15.     dc.l    $4e71            ;BKEP_ID
  16.  
  17.     moveq    #0,d7
  18.     move.l    a1,-(sp)
  19.     lea    (_tdname,pc),a1        ; _FindResident
  20.     jsr    (a2)
  21.     move.l    (sp)+,a1
  22.     tst.l    d0
  23.     beq.b    .exit
  24.     move.l    d0,a2            ; a2=trackdisk resident
  25.  
  26.     cmpi.w    #37,(12,a2)        ; V37+
  27.     bcs    .exit
  28.  
  29.     move.l    (6,a2),d1        ;endskip
  30.     sub.l    a1,d1
  31.     ror.l    #1,d1            ; Max Num of words to seach
  32.     
  33. .find    subq.l    #1,d1
  34.     beq    .ok
  35.     cmpi.w    #$3a98,(a0)+
  36.     bne.b    .find
  37.     cmpi.w    #$0a00,(a0)+
  38.     bne    .find
  39.     move.b    #1,(-1,a0)        ;set TDP_NOCLICK
  40.     bra    .find    
  41.  
  42. .ok    moveq    #1,d7
  43. .out    move.l    d7,d0
  44.     rts
  45.  
  46. .exit    lea    (_error1,pc),a0        ; a0=fmt
  47.     pea    (_tdname,pc)
  48.     move.l    sp,a1            ; a1=array
  49.     jsr    (a4)            ; Call _Printf
  50.     addq.l    #4,sp
  51.     bra    .out
  52.  
  53. _tdname    dc.b    'trackdisk.device',0
  54.  
  55. _error1    dc.b    'NoClick: This patch requires %s V37+!',10,0
  56.     dc.b    '$VER: NoClick_PATCH 1.3 (3.3.2000)',13,10,0
  57.